» IAM policy for projects

Four different resources help you manage your IAM policy for a project. Each of these resources serves a different use case:

  • google_project_iam_policy: Authoritative. Sets the IAM policy for the project and replaces any existing policy already attached.
  • google_project_iam_binding: Authoritative for a given role. Updates the IAM policy to grant a role to a list of members. Other roles within the IAM policy for the project are preserved.
  • google_project_iam_member: Non-authoritative. Updates the IAM policy to grant a role to a new member. Other members for the role for the project are preserved.
  • google_project_iam_audit_config: Authoritative for a given service. Updates the IAM policy to enable audit logging for the given service.

» google_project_iam_policy

resource "google_project_iam_policy" "project" {
  project     = "your-project-id"
  policy_data = "${data.google_iam_policy.admin.policy_data}"
}

data "google_iam_policy" "admin" {
  binding {
    role = "roles/editor"

    members = [
      "user:jane@example.com",
    ]
  }
}

» google_project_iam_binding

resource "google_project_iam_binding" "project" {
  project = "your-project-id"
  role    = "roles/editor"

  members = [
    "user:jane@example.com",
  ]
}

» google_project_iam_member

resource "google_project_iam_member" "project" {
  project = "your-project-id"
  role    = "roles/editor"
  member  = "user:jane@example.com"
}

» google_project_iam_audit_config

resource "google_project_iam_audit_config" "project" {
  project = "your-project-id"
  service = "allServices"
  audit_log_config {
    log_type = "DATA_READ"
    exempted_members = [
      "user:joebloggs@hashicorp.com",
    ]
  }
}

» Argument Reference

The following arguments are supported:

  • member/members - (Required except for google_project_iam_audit_config) Identities that will be granted the privilege in role. Each entry can have one of the following values:

    • user:{emailid}: An email address that represents a specific Google account. For example, alice@gmail.com or joe@example.com.
    • serviceAccount:{emailid}: An email address that represents a service account. For example, my-other-app@appspot.gserviceaccount.com.
    • group:{emailid}: An email address that represents a Google group. For example, admins@example.com.
    • domain:{domain}: A G Suite domain (primary, instead of alias) name that represents all the users of that domain. For example, google.com or example.com.
  • role - (Required except for google_project_iam_audit_config) The role that should be applied. Only one google_project_iam_binding can be used per role. Note that custom roles must be of the format [projects|organizations]/{parent-name}/roles/{role-name}.

  • policy_data - (Required only by google_project_iam_policy) The google_iam_policy data source that represents the IAM policy that will be applied to the project. The policy will be merged with any existing policy applied to the project.

    Changing this updates the policy.

    Deleting this removes all policies from the project, locking out users without organization-level access.

  • project - (Optional) The project ID. If not specified for google_project_iam_binding, google_project_iam_member, or google_project_iam_audit_config, uses the ID of the project configured with the provider. Required for google_project_iam_policy - you must explicitly set the project, and it will not be inferred from the provider.

  • service - (Required only by google_project_iam_audit_config) Service which will be enabled for audit logging. The special value allServices covers all services. Note that if there are google_project_iam_audit_config resources covering both allServices and a specific service then the union of the two AuditConfigs is used for that service: the log_types specified in each audit_log_config are enabled, and the exempted_members in each audit_log_config are exempted.

  • audit_log_config - (Required only by google_project_iam_audit_config) The configuration for logging of each type of permission. This can be specified multiple times. Structure is documented below.


The audit_log_config block supports:

  • log_type - (Required) Permission type for which logging is to be configured. Must be one of DATA_READ, DATA_WRITE, or ADMIN_READ.

  • exempted_members - (Optional) Identities that do not cause logging for this type of permission. The format is the same as that for members.

» Attributes Reference

In addition to the arguments listed above, the following computed attributes are exported:

  • etag - (Computed) The etag of the project's IAM policy.

» Import

IAM member imports use space-delimited identifiers; the resource in question, the role, and the account. This member resource can be imported using the project_id, role, and member e.g.

$ terraform import google_project_iam_member.my_project "your-project-id roles/viewer user:foo@example.com"

IAM binding imports use space-delimited identifiers; the resource in question and the role. This binding resource can be imported using the project_id and role, e.g.

terraform import google_project_iam_binding.my_project "your-project-id roles/viewer"

IAM policy imports use the identifier of the resource in question. This policy resource can be imported using the project_id.

$ terraform import google_project_iam_policy.my_project your-project-id

IAM audit config imports use the identifier of the resource in question and the service, e.g.

terraform import google_project_iam_audit_config.my_project "your-project-id foo.googleapis.com"