» google_bigquery_dataset

Datasets allow you to organize and control access to your tables.

» Example Usage - Bigquery Dataset Basic

resource "google_bigquery_dataset" "dataset" {
  dataset_id                  = "example_dataset"
  friendly_name               = "test"
  description                 = "This is a test description"
  location                    = "EU"
  default_table_expiration_ms = 3600000

  labels = {
    env = "default"
  }

  access {
    role          = "OWNER"
    user_by_email = "Joe@example.com"
  }
  access {
    role   = "READER"
    domain = "example.com"
  }
}

» Example Usage - Bigquery Dataset Cmek

resource "google_bigquery_dataset" "dataset" {
  dataset_id                  = "example_dataset"
  friendly_name               = "test"
  description                 = "This is a test description"
  location                    = "US"
  default_table_expiration_ms = 3600000

  default_encryption_configuration {
    kms_key_name = google_kms_crypto_key.crypto_key.self_link
  }
}

resource "google_kms_crypto_key" "crypto_key" {
  name     = "example-key"
  key_ring = google_kms_key_ring.key_ring.self_link
}

resource "google_kms_key_ring" "key_ring" {
  name     = "example-keyring"
  location = "us"
}

» Argument Reference

The following arguments are supported:

  • dataset_id - (Required) A unique ID for this dataset, without the project name. The ID must contain only letters (a-z, A-Z), numbers (0-9), or underscores (_). The maximum length is 1,024 characters.

  • access - (Optional) An array of objects that define dataset access for one or more entities. Structure is documented below.

  • default_table_expiration_ms - (Optional) The default lifetime of all tables in the dataset, in milliseconds. The minimum value is 3600000 milliseconds (one hour).

Once this property is set, all newly-created tables in the dataset will have an expirationTime property set to the creation time plus the value in this property, and changing the value will only affect new tables, not existing ones. When the expirationTime for a given table is reached, that table will be deleted automatically. If a table's expirationTime is modified or removed before the table expires, or if you provide an explicit expirationTime when creating a table, that value takes precedence over the default expiration time indicated by this property.

Once this property is set, all newly-created partitioned tables in the dataset will have an expirationMs property in the timePartitioning settings set to this value, and changing the value will only affect new tables, not existing ones. The storage in a partition will have an expiration time of its partition time plus this value. Setting this property overrides the use of defaultTableExpirationMs for partitioned tables: only one of defaultTableExpirationMs and defaultPartitionExpirationMs will be used for any new partitioned table. If you provide an explicit timePartitioning.expirationMs when creating or updating a partitioned table, that value takes precedence over the default partition expiration time indicated by this property.

  • description - (Optional) A user-friendly description of the dataset

  • friendly_name - (Optional) A descriptive name for the dataset

  • labels - (Optional) The labels associated with this dataset. You can use these to organize and group your datasets

  • location - (Optional) The geographic location where the dataset should reside. See official docs.

There are two types of locations, regional or multi-regional. A regional location is a specific geographic place, such as Tokyo, and a multi-regional location is a large geographic area, such as the United States, that contains at least two geographic places.

Possible regional values include: asia-east1, asia-northeast1, asia-southeast1, australia-southeast1, europe-north1, europe-west2 and us-east4.

Possible multi-regional values: EU and US.

The default value is multi-regional location US. Changing this forces a new resource to be created.

  • default_encryption_configuration - (Optional) The default encryption key for all tables in the dataset. Once this property is set, all newly-created partitioned tables in the dataset will have encryption key set to this value, unless table creation request (or query) overrides the key. Structure is documented below.

  • project - (Optional) The ID of the project in which the resource belongs. If it is not provided, the provider project is used.

  • delete_contents_on_destroy - (Optional) If set to true, delete all the tables in the dataset when destroying the resource; otherwise, destroying the resource will fail if tables are present.

The access block supports:

  • domain - (Optional) A domain to grant access to. Any users signed in with the domain specified will be granted the specified access

  • group_by_email - (Optional) An email address of a Google Group to grant access to.

  • role - (Optional) Describes the rights granted to the user specified by the other member of the access object. Primitive, Predefined and custom roles are supported. Predefined roles that have equivalent primitive roles are swapped by the API to their Primitive counterparts, and will show a diff post-create. See official docs.

  • special_group - (Optional) A special group to grant access to.

Possible values include:

  • projectOwners: Owners of the enclosing project.

  • projectReaders: Readers of the enclosing project.

  • projectWriters: Writers of the enclosing project.

  • allAuthenticatedUsers: All authenticated BigQuery users.

    • user_by_email - (Optional) An email address of a user to grant access to. For example: fred@example.com
    • view - (Optional) A view from a different dataset to grant access to. Queries executed against that view will have read access to tables in this dataset. The role field is not required when this field is set. If that view is updated by any user, access to the view needs to be granted again via an update operation. Structure is documented below.

The view block supports:

  • dataset_id - (Required) The ID of the dataset containing this table.

  • project_id - (Required) The ID of the project containing this table.

  • table_id - (Required) The ID of the table. The ID must contain only letters (a-z, A-Z), numbers (0-9), or underscores (_). The maximum length is 1,024 characters.

The default_encryption_configuration block supports:

  • kms_key_name - (Required) Describes the Cloud KMS encryption key that will be used to protect destination BigQuery table. The BigQuery Service Account associated with your project requires access to this encryption key.

» Attributes Reference

In addition to the arguments listed above, the following computed attributes are exported:

  • creation_time - The time when this dataset was created, in milliseconds since the epoch.

  • etag - A hash of the resource.

  • last_modified_time - The date when this dataset or any of its tables was last modified, in milliseconds since the epoch.

  • self_link - The URI of the created resource.

» Timeouts

This resource provides the following Timeouts configuration options:

  • create - Default is 4 minutes.
  • update - Default is 4 minutes.
  • delete - Default is 4 minutes.

» Import

Dataset can be imported using any of these accepted formats:

$ terraform import google_bigquery_dataset.default projects/{{project}}/datasets/{{dataset_id}}
$ terraform import google_bigquery_dataset.default {{project}}/{{dataset_id}}
$ terraform import google_bigquery_dataset.default {{dataset_id}}

» User Project Overrides

This resource supports User Project Overrides.