» azurerm_data_factory_dataset_azure_blob

Manages an Azure Blob Dataset inside an Azure Data Factory.

» Example Usage

resource "azurerm_resource_group" "example" {
  name     = "example-resources"
  location = "northeurope"
}

data "azurerm_storage_account" "example" {
  name                = "storageaccountname"
  resource_group_name = azurerm_resource_group.example.name
}

resource "azurerm_data_factory" "example" {
  name                = "example"
  location            = azurerm_resource_group.example.location
  resource_group_name = azurerm_resource_group.example.name
}

resource "azurerm_data_factory_linked_service_azure_blob_storage" "example" {
  name                = "example"
  resource_group_name = azurerm_resource_group.example.name
  data_factory_name   = azurerm_data_factory.example.name
  connection_string   = data.azurerm_storage_account.example.primary_connection_string
}

resource "azurerm_data_factory_dataset_azure_blob" "example" {
  name                = "example"
  resource_group_name = azurerm_resource_group.example.name
  data_factory_name   = azurerm_data_factory.example.name
  linked_service_name = azurerm_data_factory_linked_service_azure_blob_storage.example.name

  path     = "foo"
  filename = "bar.png"
}

» Argument Reference

The following supported arguments are common across all Azure Data Factory Datasets:

  • name - (Required) Specifies the name of the Data Factory Dataset. Changing this forces a new resource to be created. Must be globally unique. See the Microsoft documentation for all restrictions.

  • resource_group_name - (Required) The name of the resource group in which to create the Data Factory Dataset. Changing this forces a new resource

  • data_factory_name - (Required) The Data Factory name in which to associate the Dataset with. Changing this forces a new resource.

  • linked_service_name - (Required) The Data Factory Linked Service name in which to associate the Dataset with.

  • folder - (Optional) The folder that this Dataset is in. If not specified, the Dataset will appear at the root level.

  • schema_column - (Optional) A schema_column block as defined below.

  • description - (Optional) The description for the Data Factory Dataset.

  • annotations - (Optional) List of tags that can be used for describing the Data Factory Dataset.

  • parameters - (Optional) A map of parameters to associate with the Data Factory Dataset.

  • additional_properties - (Optional) A map of additional properties to associate with the Data Factory Dataset.

The following supported arguments are specific to Azure Blob Dataset:

  • path - (Required) The path of the Azure Blob.

  • filename - (Required) The filename of the Azure Blob.


A schema_column block supports the following:

  • name - (Required) The name of the column.

  • type - (Optional) Type of the column. Valid values are Byte, Byte[], Boolean, Date, DateTime,DateTimeOffset, Decimal, Double, Guid, Int16, Int32, Int64, Single, String, TimeSpan. Please note these values are case sensitive.

  • description - (Optional) The description of the column.

» Attributes Reference

The following attributes are exported:

  • id - The ID of the Data Factory Dataset.

» Timeouts

The timeouts block allows you to specify timeouts for certain actions:

  • create - (Defaults to 30 minutes) Used when creating the Data Factory Dataset.
  • update - (Defaults to 30 minutes) Used when updating the Data Factory Dataset.
  • read - (Defaults to 5 minutes) Used when retrieving the Data Factory Dataset.
  • delete - (Defaults to 30 minutes) Used when deleting the Data Factory Dataset.

» Import

Data Factory Datasets can be imported using the resource id, e.g.

terraform import azurerm_data_factory_dataset_azure_blob.example /subscriptions/00000000-0000-0000-0000-000000000000/resourceGroups/example/providers/Microsoft.DataFactory/factories/example/datasets/example